Initial commit.

git-svn-id: svn://svn.gna.org/svn/chrysalide/trunk@5 abbe820e-26c8-41b2-8c08-b7b2b41f8b0a

1 files changed, 199 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..a1d80af
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,199 @@
+# Process this file with autoconf to produce a configure script.
+
+############################################################
+# Autoconf requirements
+############################################################
+
+AC_PREREQ(2.59)
+AC_INIT([openida], [0.0.1], [nocbos@gmail.com])
+
+AC_CONFIG_HEADERS([config.h])
+AM_INIT_AUTOMAKE
+
+AM_GNU_GETTEXT_VERSION([0.17])
+AM_GNU_GETTEXT([external])
+
+AC_CONFIG_SRCDIR([src/editor.c])
+
+
+############################################################
+# Information on the package
+############################################################
+
+#--- Checks for programs
+
+AC_PROG_CC
+AC_PROG_INSTALL
+AC_PROG_MAKE_SET
+AC_PROG_RANLIB
+
+
+#--- Checks for libraries
+
+AC_CHECK_LIB([dl], [dlopen])
+
+
+#--- Checks for header files
+
+AC_HEADER_DIRENT
+AC_HEADER_STDBOOL
+AC_HEADER_STDC
+AC_CHECK_HEADERS([malloc.h])
+AC_CHECK_HEADERS([netdb.h])
+AC_CHECK_HEADERS([stdlib.h])
+AC_CHECK_HEADERS([string.h])
+AC_CHECK_HEADERS([unistd.h])
+
+
+#--- Checks for types
+
+AC_TYPE_SIZE_T
+
+
+#--- Checks for structures
+
+AC_STRUCT_TM
+
+
+#--- Checks for compiler characteristics
+
+AC_C_CONST
+
+
+#--- Checks for library functions
+
+AC_FUNC_CLOSEDIR_VOID
+AC_FUNC_MALLOC
+AC_FUNC_REALLOC
+AC_FUNC_STAT
+AC_FUNC_STRFTIME
+AC_FUNC_VPRINTF
+
+AC_CHECK_FUNCS([pow])
+AC_CHECK_FUNCS([regcomp])
+AC_CHECK_FUNCS([strdup])
+AC_CHECK_FUNCS([strerror])
+AC_CHECK_FUNCS([strndup])
+AC_CHECK_FUNCS([strrchr])
+
+
+#--- Checks for system services
+
+
+
+#--- Autoheader Macros
+
+AH_TEMPLATE([VERSION], [Define the version number of the program for the about box.])
+AH_TEMPLATE([PACKAGE_DATA_DIR], [Define the directory where the associated data will be installed.])
+AH_TEMPLATE([PACKAGE_SOURCE_DIR], [Define the directory where the code source is waiting for being compiled.])
+AH_TEMPLATE([LOCALE_DIR], [Define the directory where the message catalogs are installed.])
+
+
+AC_DEFINE_UNQUOTED(VERSION, AC_PACKAGE_VERSION)
+
+if test "x${datadir}" = 'x${prefix}/share'; then
+   if test "x${prefix}" = "xNONE"; then
+      AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
+   else
+      AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
+   fi
+elif test "x${datadir}" = 'x${datarootdir}'; then
+   if test "x${datarootdir}" = 'x${prefix}/share'; then
+      if test "x${prefix}" = "xNONE"; then
+         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
+      else
+         AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
+      fi
+   else
+      AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datarootdir}/${PACKAGE}")
+   fi 
+else
+   AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
+fi
+
+packagesrcdir=`cd $srcdir && pwd`
+AC_DEFINE_UNQUOTED(PACKAGE_SOURCE_DIR, "${packagesrcdir}")
+
+if test "x${prefix}" = "xNONE"; then
+   AC_DEFINE_UNQUOTED(LOCALE_DIR, "${ac_default_prefix}/share/locale")
+else
+   AC_DEFINE_UNQUOTED(LOCALE_DIR, "${prefix}/share/locale")
+fi
+
+
+############################################################
+# Compilation options
+############################################################
+
+AC_ARG_ENABLE(debug,        [  --enable-debug          compile with debugging support [def=no]],            [enable_debug=yes],     [enable_debug=no])
+
+
+#--- Is debug mode needed ?
+
+if test "x$enable_debug" = "xyes"; then
+   DEBUG_CFLAGS="$DEBUG_CFLAGS -ggdb -gdwarf-2 -DDEBUG"
+fi
+
+AC_SUBST(DEBUG_CFLAGS)
+
+#-Wall -Wimplicit -Wreturn-type -Wunused -Wswitch -Wcomment -Wuninitialized -Wparentheses -Wpointer-arith -Wmissing-prototypes
+
+WARNING_FLAGS="-Wall -Wimplicit -Wreturn-type -Wunused -Wswitch -Wcomment -Wuninitialized -Wparentheses -Wpointer-arith -Wmissing-prototypes"
+
+#-Wcast-qual -Wconversion -Wsign-compare -Wdisabled-optimization
+
+AC_SUBST(WARNING_FLAGS)
+
+#--- Checks for GTK 2.0
+
+PKG_CHECK_MODULES(LIBGTK,gtk+-2.0 >= 2.4.3,[libgtk_found=yes],[libgtk_found=no])
+
+if test "$libgtk_found" = "yes"; then
+   libgtk_version=`pkg-config gtk+-2.0 --modversion`
+else
+   libgtk_version='-'
+fi
+
+AC_SUBST(LIBGTK_CFLAGS)
+AC_SUBST(LIBGTK_LIBS)
+
+
+#--- Checks for libxml2
+
+PKG_CHECK_MODULES(LIBXML,libxml-2.0 >= 2.6.11,[libxml_found=yes],[libxml_found=no])
+
+if test "$libxml_found" = "yes"; then
+   libxml_version=`pkg-config libxml-2.0 --modversion`
+else
+   libxml_version='-'
+fi
+
+AC_SUBST(LIBXML_CFLAGS)
+AC_SUBST(LIBXML_LIBS)
+
+
+############################################################
+# Outputting files
+############################################################
+
+AC_CONFIG_FILES([stamp-h po/Makefile.in], [echo timestamp > stamp-h])
+
+AC_CONFIG_FILES([Makefile
+                 src/Makefile])
+
+AC_OUTPUT
+
+
+echo
+echo $PACKAGE $VERSION
+
+echo
+echo The GNU Image Manipulation Program Toolkit... : $libgtk_version
+echo The XML C parser and toolkit of Gnome........ : $libxml_version
+
+echo
+echo Print debugging messages..................... : $enable_debug
+
+echo
+echo configure complete, now type \'make\'
+echo