1 files changed, 149 insertions, 0 deletions
diff --git a/src/format/mangling/dex/type_gram.y b/src/format/mangling/dex/type_gram.y
new file mode 100644
index 0000000..1176bd2
--- /dev/null
+++ b/src/format/mangling/dex/type_gram.y
@@ -0,0 +1,149 @@
+
+%{
+
+#include <stdbool.h>
+
+
+#include "context.h"
+#include "../context-int.h"
+
+
+
+/* Affiche un message d'erreur concernant l'analyse. */
+static int type_error(GDexDemangler *, char *);
+
+/* Procède au décodage d'une chaîne de caractères. */
+bool demangle_dex_type(GDexDemangler *, const char *);
+
+
+%}
+
+
+%code requires {
+
+#include "../../../analysis/types/basic.h"
+#include "../../../analysis/types/cse.h"
+
+}
+
+%union {
+
+    GDataType *type;                        /* Type reconstruit            */
+    size_t adeep;                           /* Dimension d'un tableau      */
+    char *text;                             /* Chaîne de caractères        */
+
+}
+
+
+%parse-param { GDexDemangler *demangler }
+
+%token V Z B S C I J F D
+%token ARRAY
+%token L SEMICOLON
+%token SLASH DOLLAR
+%token TEXT
+
+%type <type> type_descriptor field_type_descriptor non_array_field_type_descriptor full_class_name
+
+%type <text> TEXT
+
+
+%{
+
+/* Déclarations issues de l'analyseur syntaxique... */
+
+typedef struct yy_buffer_state *YY_BUFFER_STATE;
+
+extern YY_BUFFER_STATE type__scan_string(const char *);
+extern void type__delete_buffer(YY_BUFFER_STATE);
+extern int type_lex(void);
+
+%}
+
+
+%%
+
+
+input:
+    type_descriptor                     { G_DEMANGLING_CONTEXT(demangler)->type = $1; }
+
+type_descriptor:
+    V                                   { $$ = g_basic_type_new(BTP_VOID); }
+    | field_type_descriptor             { $$ = $1; }
+
+field_type_descriptor:
+	non_array_field_type_descriptor             { $$ = $1; }
+	| ARRAY non_array_field_type_descriptor     { $$ = $2; }
+
+non_array_field_type_descriptor:
+	Z                                   { $$ = g_basic_type_new(BTP_BOOL); }
+	| B                                 { $$ = g_basic_type_new(BTP_UCHAR); }
+	| S                                 { $$ = g_basic_type_new(BTP_SHORT); }
+	| C                                 { $$ = g_basic_type_new(BTP_CHAR); }
+	| I                                 { $$ = g_basic_type_new(BTP_INT); }
+	| J                                 { $$ = g_basic_type_new(BTP_LONG); }
+	| F                                 { $$ = g_basic_type_new(BTP_FLOAT); }
+	| D                                 { $$ = g_basic_type_new(BTP_DOUBLE); }
+	| L full_class_name SEMICOLON       { $$ = $2; }
+
+full_class_name:
+    TEXT                                { $$ = g_class_enum_type_new(CET_CLASS, $1); }
+    | full_class_name SLASH TEXT        {
+                                            $$ = g_class_enum_type_new(CET_CLASS, $3);
+                                            g_data_type_set_namespace($$, $1);
+                                            g_object_unref($1);
+                                        }
+    | full_class_name DOLLAR TEXT       {
+                                            $$ = g_class_enum_type_new(CET_CLASS, $3);
+                                            g_data_type_set_namespace($$, $1);
+                                            g_object_unref($1);
+                                        }
+
+
+%%
+
+
+/******************************************************************************
+*                                                                             *
+*  Paramètres  : demangler = contexte associé à la procédure de décodage.     *
+*                msg       = indications humaines sur l'événement.            *
+*                                                                             *
+*  Description : Affiche un message d'erreur concernant l'analyse.            *
+*                                                                             *
+*  Retour      : Valeur historique, ignorée.                                  *
+*                                                                             *
+*  Remarques   : -                                                            *
+*                                                                             *
+******************************************************************************/
+static int type_error(GDexDemangler *demangler, char *msg)
+{
+	return -1;
+
+}
+
+
+/******************************************************************************
+*                                                                             *
+*  Paramètres  : demangler = contexte de décodage à utiliser.                 *
+*                desc      = chaîne de caractères à décoder.                  *
+*                                                                             *
+*  Description : Procède au décodage d'une chaîne de caractères.              *
+*                                                                             *
+*  Retour      : Bilan de l'opération.                                        *
+*                                                                             *
+*  Remarques   : -                                                            *
+*                                                                             *
+******************************************************************************/
+
+bool demangle_dex_type(GDexDemangler *demangler, const char *desc)
+{
+	YY_BUFFER_STATE buffer;                 /* Tampon pour bison           */
+	int ret;                                /* Bilan de l'appel            */
+
+	buffer = type__scan_string(desc);
+	ret = yyparse(demangler);
+	type__delete_buffer(buffer);
+
+    return (ret == 0);
+
+}